feat: nix: rename hp_ssh_wasm to headplane-ssh-wasm for consistency

nix/ssh-wasm.nix

@@ -0,0 +1,33 @@
+{
+  buildGoModule,
+  go,
+}: let
+  wasmExecJs =
+    if builtins.pathExists "${go}/share/go/lib/wasm/wasm_exec.js"
+    then "${go}/share/go/lib/wasm/wasm_exec.js"
+    else if builtins.pathExists "${go}/lib/wasm/wasm_exec.js"
+    then "${go}/lib/wasm/wasm_exec.js"
+    else "${go}/share/go/misc/wasm/wasm_exec.js";
+in
+  buildGoModule {
+    pname = "headplane-ssh-wasm";
+    version = (builtins.fromJSON (builtins.readFile ../package.json)).version;
+    src = ../.;
+    subPackages = ["cmd/hp_ssh"];
+    vendorHash = "sha256-3hZzDORAH+D4FW6SkOv3Enddd+q36ZALryvCPD9E5Ac=";
+    env.CGO_ENABLED = 0;
+
+    nativeBuildInputs = [go];
+
+    buildPhase = ''
+      export GOOS=js
+      export GOARCH=wasm
+      go build -o hp_ssh.wasm ./cmd/hp_ssh
+    '';
+
+    installPhase = ''
+      mkdir -p $out
+      cp hp_ssh.wasm $out/
+      cp ${wasmExecJs} $out/wasm_exec.js
+    '';
+  }